Houdini 에서 바로
실행되는 마법 같은
렌더링

튜토리얼구 쉐이더

적용되는 기술을 살펴볼 수 있는 간단한 예시에서 시작하겠습니다. 이 예에서는 쉐이더에서 렌더링된 장면을 정의합니다(현재는 구, 나중에는 프랙털). 그러면 쉐이딩된 각 샘플의 밀도 값이 표시됩니다. 지정된 경계로 볼륨을 렌더링하기 위해 상자를 만든 후 볼륨으로 렌더링할 수 있습니다.

• 먼저 Uniform Scale 을 2로 설정하여 상자를 만듭니다. 볼륨 Step Size 를 0보다 큰 값(예: 0.1) 으로 설정하여 메쉬를 볼륨으로 렌더링합니다.
• Arnold ROP, 카메라 및 라이트를 생성하여 결과를 확인합니다.
• Material Output 노드에서 Volume 슬롯에 Standard Volume 이 연결된 쉐이더를 생성합니다.

Render View 창에서 Render 버튼을 누릅니다. 렌더링되는 볼륨 큐브를 확인할 수 있습니다.

이제 표준 컨텐츠를 사용하여 쉐이더를 조정하여 모양을 정의할 수 있습니다. 현재 설정은 상자 경계 내, 즉 상자 내 어디서나 균일한 밀도를 출력합니다. 좀 더 흥미로운 구를 살펴보겠습니다. 여기서 구 볼륨은 중심까지의 거리가 구의 반지름보다 작거나 같은 모든 점으로 가득 찬 암시적 볼륨으로 정의할 수 있습니다. 나머지는 비어 있습니다. 이 정의는 다음 의사 코드로 다시 작성할 수 있습니다.

if (length(P_world) <= sphere_radius) 
    density = 1
else
    density = 0

sphere_shader.osl

shader sphere_shader(
    float sphere_radius = 1.0,
    output float density = 0.0
)
{
    if (length(P) <= sphere_radius)
        density = 1.0;
    else
        density = 0.0;
}

ARNOLD_PLUGIN_PATH = /path/to/folder/with/osl/shaders

mandelbulb_shader.osl

shader mandelbulb_shader(
    float power = 8.0,
    int julia_enable = 0 [[ string widget = "boolean" ]],
    vector julia_coordinate = vector(0, 0, 0),
    int max_iterations = 150,
    float max_distance = 20.0,
    output float density = 0
)
{
    point P_in = P;
    point Z = P;
    int i;
    for (i = 0; i < max_iterations; i++)
    {      
        float distance = length(Z);
        // convert to polar coordinates
        float theta = acos(Z[2] / distance);
        float phi = atan2(Z[1], Z[0]);
         
        // scale and rotate the point
        float zr = pow(distance, power);
        theta *= power;
        phi *= power;
         
        // convert back to cartesian coordinates
        point new_Z = zr * point( sin(theta)*cos(phi), sin(phi)*sin(theta), cos(theta) );
        // update our point in normal or julia mode
        if (julia_enable == 0)
        {
            Z = new_Z + P_in;
        }
        else
        {
            Z = new_Z + julia_coordinate;
        }
        distance = length(Z);
        if (distance > max_distance) break;
    }
    // define density: 1 where point did not escape, 0 where point escaped to infinity
    if (i == max_iterations)
        density = 1.0;
    else
        density = 0.0;
}

mandelbulb_colors_shader.osl

// squared length
float length2(vector vec)
{
    return dot(vec, vec);
}
// point to plane distance
float distPointPlane(vector pt, vector plane_n, vector plane_point)
{
    float sb, sn, sd;
    vector point_proj;
    sn = -dot( plane_n, (pt - plane_point));
    sd = dot(plane_n, plane_n);
    sb = sn / sd;
    point_proj = pt + sb * plane_n;
     
    return length(pt - point_proj);
}
shader mandelbulb_colors_shader(
    float power = 8.0,
    int julia_enable = 0 [[ string widget = "boolean" ]],
    vector julia_coordinate = vector(0, 0, 0),
    int max_iterations = 150,
    float max_distance = 20.0,
    output matrix out = 0
)
{
    point P_in = P;
    point Z = P;
    int i;
    // orbit traps
    float orbit_coord_dist = 100000;
    float orbit_sphere_dist = 100000;
    point orbit_plane_origin = point(0.0);
    vector orbit_plane_dist = vector(100000);
    for (i = 0; i < max_iterations; i++)
    {      
        float distance = length(Z);
        // convert to polar coordinates
        float theta = acos(Z[2] / distance);
        float phi = atan2(Z[1], Z[0]);
         
        // scale and rotate the point
        float zr = pow(distance, power);
        theta *= power;
        phi *= power;
         
        // convert back to cartesian coordinates
        point new_Z = zr * point( sin(theta)*cos(phi), sin(phi)*sin(theta), cos(theta) );
        // update our point in normal or julia mode
        if (julia_enable == 0)
        {
            Z = new_Z + P_in;
        }
        else
        {
            Z = new_Z + julia_coordinate;
        }
        distance = length(Z);
        if (distance > max_distance) break;
        // orbit traps
        orbit_coord_dist = min(orbit_coord_dist, fabs( length2(Z - P_in) ));
        orbit_sphere_dist = min( orbit_sphere_dist, fabs( length2(Z - point(0)) - 2.0) );
        orbit_plane_dist[0] = min( orbit_plane_dist[0], distPointPlane(Z, vector(1.0, 0.0, 0.0), orbit_plane_origin) );
        orbit_plane_dist[1] = min( orbit_plane_dist[1], distPointPlane(Z, vector(0.0, 1.0, 0.0), orbit_plane_origin) );
        orbit_plane_dist[2] = min( orbit_plane_dist[2], distPointPlane(Z, vector(0.0, 0.0, 1.0), orbit_plane_origin) );
    }
    // orbit traps
    orbit_coord_dist = sqrt(orbit_coord_dist);
    orbit_sphere_dist = sqrt(orbit_sphere_dist);
    // define density: 1 where point did not escape, 0 where point escaped to infinity
    float density;
    if (i == max_iterations)
        density = 1.0;
    else
        density = 0.0;
     
    // output values
    out[0][0] = density;
    out[0][1] = orbit_coord_dist;
    out[0][2] = orbit_sphere_dist;
    out[0][3] = orbit_plane_dist[0];
    out[1][0] = orbit_plane_dist[1];
    out[1][1] = orbit_plane_dist[2];
}

get_matrix_element.osl

shader vft_get_matrix_element(
    matrix mat = 1,
    int row = 0,
    int column = 0,
    output float element_out = 0.0
)
{
    element_out = mat[row][column];
}

Mandelbulb 쉐이더를 기반으로 동일한 인덱스를 사용하여 값을 추출하고 쉐이딩에 사용할 수 있습니다. 창의적으로 값을 조정하고 조합하여 시각적으로 흥미로운 이미지를 만들어 보십시오. 다음 이미지에서는 두 가지 다른 색을 혼합하는 데 궤도 트랩이 사용되었으며 Standard Volume 노드에서 Scatter Color 매개변수를 유도하고 있습니다.

자세히 알아보기프랙털 품질 설정

볼륨 장면에서 세부 정보의 양을 제어하는 첫 번째 옵션은 경계 상자 객체의 볼륨 Step Size입니다. 숫자가 작을수록 렌더링된 볼륨이 자세하게 표시됩니다. 차이를 확인할 수 없을 때까지 낮은 값으로 설정해 보십시오. 너무 낮게 설정하면 렌더 시간에 부정적인 영향을 미칩니다.